2週目

1週目で学んだことを活かして、組み合わせてみましょう。

注釈

一部古い記述がふくまれています。Arduino IDE → arduino-cli におきかえてください。

複数人で書いたプログラムを統合する

Arduino IDEでは、プログラムを複数のファイル(たとえば、main.ino / sub.ino / hoge.cpp / hoge.h ) に分割して記述することができます。複数ファイルに分割することで、関数定義を機能別にまとめることができ、管理しやすくなります。
Arduino IDEでは、プログラムを構成する、複数のファイル（スケッチブック）を、1つのフォルダに入れて管理します。（スケッチブックのことを、他のIDEでは「プロジェクト」と呼ぶ場合もある）
スケッチブックに別のファイル(hogehoge.ino) を追加するには、右上にあるシリアルモニタをひらくアイコンの、下の「▼」ボタンからメニューをひらき、「新規タブ」を選択し、ファイル名(拡張子.ino をのぞいた、hogehogeの部分のみ)を入力します。
スケッチブックをコピーしたいときは、内包するフォルダごとコピーしてください。その際、フォルダ名と、メインのソースコードファイル名（拡張子以外の部分）は、一致している必要があります。
複数のファイルを置いたときの挙動について： ***.ino ファイルの内容は、単純にメインのタブ（フォルダ名と同じinoファイル）にマージされます。***.cpp や ***.c という拡張子でファイルを作成した場合は、***.h を作成する必要があります。参考：Properly using separate tabs with Arduino IDE
Git を利用すると、複数人で作業したファイルを統合しやすいです。

タスク

複数の機能を1つの loop() にまとめようとすると、プログラムが複雑になります。タスクを用いると、 loop() に相当する関数を複数定義し、並列に動作させることができます。

リスト 26 に、タスクを利用する例を示します。3つの異なるタスクを作成し、それぞれの関数内部で setup() と loop() に相当する処理を記述しています。引数の詳細については、非公式日本語リファレンスを参照してください。ここの例では、1つのファイルに記述していますが、タスクごとに別のファイルにすることもできます。以下の例ではタスク生成時に、タスクハンドル TaskHandle_t を設定しています。タスクハンドルは、タスクの一時停止（サスペンド）や、再開（レジューム）、削除のときにタスクを特定するために必要となります。

リスト 26 src/task01.ino

#include <M5Unified.h>

int interval_msec[] = { 333, 1000, 2000 }; // Led, Lcd, Beep
TaskHandle_t tH[3];

void ledTask(void *pvParam) {
  /** setup をここに書く **/
  portTickType lastTime;
  int PIN = 10;
  pinMode(PIN, OUTPUT); // PINのモード設定
  int highOrLow = 0;
  for (;;) {
    /** loop をここに書く **/
    lastTime = xTaskGetTickCount();
    vTaskDelayUntil(&lastTime, interval_msec[0] ); // 第2引数に、実行間隔ミリ秒を指定
    digitalWrite(PIN, highOrLow); // HIGH = 1, LOW = 0
    highOrLow = 1 - highOrLow; // HIGH <=> LOW を切り替える
  }
}

void lcdTask(void *pvParam) {
  /** setup をここに書く **/
  portTickType lastTime;
  M5.Display.setRotation(0);
  M5.Display.fillScreen(GREEN);
  M5.Display.setTextColor(WHITE, OLIVE);
  M5.Display.setTextSize(2);
  M5.Display.setCursor(0, 0);
  int count = 0;
  for (;;) {
    /** loop をここに書く **/
    M5.Display.printf("count=%d\n", count);
    count++;
    lastTime = xTaskGetTickCount();
    vTaskDelayUntil(&lastTime, interval_msec[1] ); // 第2引数に、実行間隔ミリ秒を指定
    if (count % 10 == 0) {
      M5.Display.fillScreen(GREEN);
      M5.Display.setCursor(0, 0);
    }
  }
}

void beepTask(void *pvParam) {
  /** setup をここに書く **/
  portTickType lastTime;
  int f[8] = { 262, 294, 330, 349, 392, 440, 494, 524 };
  int note = 0;
  for (;;) {
    /** loop をここに書く **/
    lastTime = xTaskGetTickCount(); // ここでの時刻を変数に保存
    tone(GPIO_NUM_2, f[note], 500);  M5.Display.setBrightness(255);
    M5.delay(500); //0.5秒鳴らす
    note = (note+1)%8;
    vTaskDelayUntil(&lastTime, interval_msec[2] ); 
    // 途中の処理やdelayは含まず、「保存」時刻の2秒後まで待つ。
  }
}

void setup() {
  auto cfg = M5.config();
  cfg.serial_baudrate = 115200;
  M5.begin(cfg);

  xTaskCreatePinnedToCore(ledTask , "LedT", 4096, NULL, 1, &tH[0],  1/*<= CoreNo.*/ );
  xTaskCreatePinnedToCore(lcdTask , "LcdT", 4096, NULL, 1, &tH[1],  1/*<= CoreNo.*/ );
  xTaskCreatePinnedToCore(beepTask,"BeepT", 4096, NULL, 1, &tH[2],  0/*<= CoreNo.*/ );
}

void loop() {
  delay(10);
}

注釈

参考： FreeRTOSでマルチタスク (on ESP32)

タスク生成時に、引数を渡すこともできます。リスト 27 に、引数を渡す例を示します。（次で述べるミューテックスを使って、排他制御もしています。）

リスト 27 src/task02.ino

#include <M5Unified.h>

xSemaphoreHandle mutex; //ミューテックス(排他制御用)

void withArgTask(void *pvParam) {
  int num = *(int*) pvParam; // 引数は、グローバル変数のアドレスをポインタで渡す
  BaseType_t mStatus;
  char* tsknm = pcTaskGetTaskName(NULL); //自タスク名を取得するならNULL、他タスク名を取得するならタスクハンドルを引数に指定する。
  while (1) {
    mStatus = xSemaphoreTake(mutex, 500); // ミューテックスを取得
    if (mStatus == pdPASS) {
      Serial.println("----");
      Serial.printf("[%s] ", tsknm );
      M5.Display.println("----");
      M5.Display.printf("[%s] ", tsknm );
      delay(500);
      for (int i = 1; i < 6; i++) {
        Serial.printf("%d ", i * num);
        M5.Display.printf("%d ", i * num);
        delay(300);
      }
      delay(300);
      Serial.printf("done \n");
      M5.Display.printf("done \n");
      delay(300);
      xSemaphoreGive(mutex); // ミューテックスを解放
      vTaskDelete(NULL); // 自タスクを削除する
    } else {
      delay(random(10,100)); //ミューテックスがとれなかったらランダムに待つ
    }
  }
}

int arg[] = {2, 3, 5, 7, 11} ;
char tskname[5];

void setup() {
  auto cfg = M5.config();
  cfg.serial_baudrate = 115200;
  M5.begin(cfg);
  M5.Display.setRotation(3); //横向き
  M5.Display.setFont(&fonts::lgfxJapanGothic_16);
  M5.Display.println("シリアルにも出力します");
  M5.Display.setTextScroll(true);

  mutex = xSemaphoreCreateMutex(); // ミューテックス作成
}

void loop() {
  Serial.println("-------");
  if (mutex != NULL) { // ミューテックスの作成に成功していたら
    for (int i = 0; i < 5; i++) {
      sprintf(tskname, "x%d", arg[i]);
      xTaskCreatePinnedToCore(withArgTask, tskname, 4096, &arg[i], 1, NULL , 1);
    }
  }
  M5.delay(20 * 1000); // 次のタスクの仕込みまで、20秒待つ
}

警告

引数をアドレスで渡すとき、関数内で宣言したローカル変数は使えません。グローバルな変数を使用する必要があります。

ミューテックスとセマフォ

複数のタスクを並列動作させると、リソース（入出力や、メモリ）に複数のタスクが同時アクセスすることで意図しない動作を引き起こすことがあります。ミューテックス(mutex: mutual exclusion)を用いると、リソースに同時にアクセスするタスクを1つに限定することができます。これを「排他制御」と呼びます。

リスト 27 の例では、ミューテックスをつかって、1つのタスクの動作（シリアルコンソールへの書き込み）が終わるまで、他のタスクが待つ例です。このように、常時動いているタスクに対して、一時停止したり、処理を制限したりするのがミューテックスの使い方です。（参考：ESP32のFreeRTOS入門その6 セマフォとミューテックス）

これに対して、セマフォは、基本的には待機・一時停止状態にあるタスクに対して、動作許可を与える用途で使用されます。動作許可を与える主体・タイミングとしては、他のタスクや、「割り込み(ISR: interrupt service routine)」からになります。ただし、バイナリセマフォを用いるより、RTOS Task Notifications を用いたほうが、高速かつメモリ使用量を削減できるようです。

バイナリセマフォは、タスク間またはタスクと割り込み間の同期に適しています。
バイナリセマフォとミューテックスは似ていますが、いくつか本質的な違いがあります。ミューテックスは優先度を継承する機構が備わっていますが、バイナリセマフォには備わっていません。

注釈

参考: RTOS binary semaphore API

キュー

参考：ESP32のFreeRTOS入門その5 キュー

FreeRTOSと、その他のRTOS

今回の実験では、Arduino IDEでのM5StickCPlusプログラミングを行ってきました。これまでArduino IDEでM5StickCPlusに書き込んできたプログラムは、FreeRTOS (RealTime OS) というRTOSの仕組みをつかって動作しています。いいかえると、ESP32プロセッサ上で、FreeRTOS プログラミングをしていたことになります。ちなみに、M5StickCPlusのような画面やブザー、センサがついていない ESP32プロセッサ開発ボードも販売されています。

MCU RTOS習得(2020年版) http://happytech.jp/bRTOS.html

その他のRTOSには、T-Kernel や ThreadX があります。こちらも、限られた資源（メモリやプロセッサ）で、厳密な処理時間管理が行える仕組みが備わっています。

参考：2020年度情報通信工学実験1 リアルタイムプログラミング【RTP】